if exist d: (
rem 用户下载路径
mkdir "D:\Users\%USERNAME%\Downloads"
xcopy "%SYSTEMDRIVE%\Users\%USERNAME%\Downloads" "D:\Users\%USERNAME%\Downloads" /H /E /K
reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders" /v "{374DE290-123F-4565-9164-39C4925E467B}" /t REG_EXPAND_SZ /d "D:\Users\%USERNAME%\Downloads" /f
reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders" /v "{7D83EE9B-2244-4E70-B1F5-5393042AF1E4}" /t REG_EXPAND_SZ /d "D:\Users\%USERNAME%\Downloads" /f
reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "{374DE290-123F-4565-9164-39C4925E467B}" /t REG_SZ /d "D:\Users\%USERNAME%\Downloads" /f
echo D:\Users\%USERNAME%\Downloads > "%SYSTEMDRIVE%\Users\%USERNAME%\Downloads\下载已迁移至D盘.txt"

rem 用户桌面路径
mkdir "D:\Users\%USERNAME%\Desktop"
xcopy "%SYSTEMDRIVE%\Users\%USERNAME%\Desktop" "D:\Users\%USERNAME%\Desktop" /H /E /K
reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders" /v "Desktop" /t REG_EXPAND_SZ /d "D:\Users\%USERNAME%\Desktop" /f
reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders" /v "{754AC886-DF64-4CBA-86B5-F7FBF4FBCEF5}" /t REG_EXPAND_SZ /d "D:\Users\%USERNAME%\Desktop" /f
reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Desktop" /t REG_SZ /d "D:\Users\%USERNAME%\Desktop" /f
echo D:\Users\%USERNAME%\Desktop > "%SYSTEMDRIVE%\Users\%USERNAME%\Desktop\桌面已迁移至D盘.txt"

rem 用户文档路径
mkdir "D:\Users\%USERNAME%\Documents"
xcopy "%SYSTEMDRIVE%\Users\%USERNAME%\Documents" "D:\Users\%USERNAME%\Documents" /H /E /K
reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders" /v "Personal" /t REG_EXPAND_SZ /d "D:\Users\%USERNAME%\Documents" /f
reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders" /v "{F42EE2D3-909F-4907-8871-4C22FC0BF756}" /t REG_EXPAND_SZ /d "D:\Users\%USERNAME%\Documents" /f
reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Personal" /t REG_SZ /d "D:\Users\%USERNAME%\Documents" /f
echo D:\Users\%USERNAME%\Documents > "%SYSTEMDRIVE%\Users\%USERNAME%\Documents\文档已迁移至D盘.txt"

gpupdate /force
) else echo.

win7 迁移用户文件到D盘

if exist d: (
rem 用户下载路径
del "%SYSTEMDRIVE%\Users\%USERNAME%\Links\Downloads.lnk"
mkdir "D:\Users\%USERNAME%\Downloads"
xcopy "%SYSTEMDRIVE%\Users\%USERNAME%\Downloads" "D:\Users\%USERNAME%\Downloads" /H /E /K
reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders" /v "{374DE290-123F-4565-9164-39C4925E467B}" /t REG_EXPAND_SZ /d "D:\Users\%USERNAME%\Downloads" /f
reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "{374DE290-123F-4565-9164-39C4925E467B}" /t REG_SZ /d "D:\Users\%USERNAME%\Downloads" /f
echo D:\Users\%USERNAME%\Downloads > "%SYSTEMDRIVE%\Users\%USERNAME%\Downloads\下载已迁移至D盘.txt"

rem 用户桌面路径
mkdir "D:\Users\%USERNAME%\Desktop"
xcopy "%SYSTEMDRIVE%\Users\%USERNAME%\Desktop" "D:\Users\%USERNAME%\Desktop" /H /E /K
reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders" /v "Desktop" /t REG_EXPAND_SZ /d "D:\Users\%USERNAME%\Desktop" /f
reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Desktop" /t REG_SZ /d "D:\Users\%USERNAME%\Desktop" /f
echo D:\Users\%USERNAME%\Desktop > "%SYSTEMDRIVE%\Users\%USERNAME%\Desktop\桌面已迁移至D盘.txt"

rem 用户文档路径
mkdir "D:\Users\%USERNAME%\Documents"
xcopy "%SYSTEMDRIVE%\Users\%USERNAME%\Documents" "D:\Users\%USERNAME%\Documents" /H /E /K
reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders" /v "Personal" /t REG_EXPAND_SZ /d "D:\Users\%USERNAME%\Documents" /f
reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "Personal" /t REG_SZ /d "D:\Users\%USERNAME%\Documents" /f
echo D:\Users\%USERNAME%\Documents > "%SYSTEMDRIVE%\Users\%USERNAME%\Documents\文档已迁移至D盘.txt"

gpupdate /force
) else echo.

用户文件夹迁移进阶版

来自IT天空 magicgenius ::: tip 转移用户文件夹到指定位置。Windows 7/10/11 测试成功!

默认将用户文件转移到 D:\Users 文件夹下，包括：桌面、音乐、文档、图片、搜索、收藏夹、视频、链接、联系人、保存的游戏。下载文件夹直接放到D盘根目录，即 D:\Downloads。可自行更改位置。

::设置目标分区盘符 Set "UD=D:"

::设置目标用户文件夹 Set "UF=D:\Users"

修改下载文件夹位置，将 UD=D: 中的 D: 改为期望的路径。修改用户文件夹位置，将 UF=D:\Users 中的 D:\Users 改为期望的路径。 :::

@echo off
::==========================================
>NUL 2>&1 REG.exe query "HKU\S-1-5-19" || (
    ECHO SET UAC = CreateObject^("Shell.Application"^) > "%TEMP%\Getadmin.vbs"
    ECHO UAC.ShellExecute "%~f0", "%1", "", "runas", 1 >> "%TEMP%\Getadmin.vbs"
    "%TEMP%\Getadmin.vbs"
    DEL /f /q "%TEMP%\Getadmin.vbs" 2>NUL
    Exit /b
)
::==========================================

mode con cols=48 lines=4
color 9f
Title 用户文件夹转移位置
::封装下面一条可删除
echo.&echo 转移前请关闭所有打开的程序！按任意键继续……&pause>nul
::封装下面一条可删除
echo.&echo 正在转移，请稍候！&echo.

taskkill /f /im explorer.exe >nul

:Start
::设置目标分区盘符
Set "UD=D:"

::设置目标用户文件夹
Set "UF=D:\Users"

Set "SF=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders"
Set "USF=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders"

::创建目标用户文件夹
robocopy %SystemDrive%\Users "%UF%" /copyall >nul 2>nul
set "icon=117"
ver|find "10.0.22" >NUL && set "icon=83"
cmd /u /c echo IconResource^=%SystemRoot%\system32\imageres.dll,%icon%>>%UF%\desktop.ini

::收藏夹(Favorites)
for /f "tokens=2,*" %%i in ('reg query "%SF%" /v "Favorites"') do set "Favorites=%%j"
cd /d "%Favorites%"
cd..
set "OldUsers=%cd%"
if "%OldUsers%" EQU "%UF%" goto :End

robocopy "%Favorites%" "%UF%\Favorites" /e /copyall /move >nul 2>nul
reg add "%SF%" /v "Favorites" /t REG_SZ /d "%UF%\Favorites" /f >nul 2>nul
reg add "%USF%" /v "Favorites" /t REG_EXPAND_SZ /d "%UF%\Favorites" /f >nul 2>nul

::桌面(Desktop）
for /f "tokens=2,*" %%i in ('reg query "%SF%" /v "Desktop"') do set "Desktop=%%j"
robocopy "%Desktop%" "%UF%\Desktop" /e /copyall /move >nul 2>nul
reg add "%SF%" /v "Desktop" /t REG_SZ /d "%UF%\Desktop" /f >nul 2>nul
reg add "%USF%" /v "Desktop" /t REG_EXPAND_SZ /d "%UF%\Desktop" /f >nul 2>nul
reg add "%USF%" /v "{754AC886-DF64-4CBA-86B5-F7FBF4FBCEF5}" /t REG_EXPAND_SZ /d "%UF%\Desktop" /f >nul 2>nul

::视频(Videos)
for /f "tokens=3,*" %%i in ('reg query "%SF%" /v "My Video"') do set "Videos=%%j"
robocopy "%Videos%" "%UF%\Videos" /e /copyall /move >nul 2>nul
reg add "%SF%" /v "My Video" /t REG_SZ /d "%UF%\Videos" /f >nul 2>nul
reg add "%USF%" /v "My Video" /t REG_EXPAND_SZ /d "%UF%\Videos" /f >nul 2>nul
reg add "%USF%" /v "{35286A68-3C57-41A1-BBB1-0EAE73D76C95}" /t REG_EXPAND_SZ /d "%UF%\Videos" /f >nul 2>nul

::图片(Pictures)
for /f "tokens=3,*" %%i in ('reg query "%SF%" /v "My Pictures"') do set "Pictures=%%j"
robocopy "%Pictures%" "%UF%\Pictures" /e /copyall /move >nul 2>nul
reg add "%SF%" /v "My Pictures" /t REG_SZ /d "%UF%\Pictures" /f >nul 2>nul
reg add "%USF%" /v "My Pictures" /t REG_EXPAND_SZ /d "%UF%\Pictures" /f >nul 2>nul
reg add "%USF%" /v "{0DDD015D-B06C-45D5-8C4C-F59713854639}" /t REG_EXPAND_SZ /d "%UF%\Pictures" /f >nul 2>nul

::联系人(Contacts)
for /f "tokens=2,*" %%i in ('reg query "%SF%" /v "{56784854-C6CB-462B-8169-88E350ACB882}"') do set "Contacts=%%j"
robocopy "%Contacts%" "%UF%\Contacts" /e /copyall /move >nul 2>nul
reg add "%SF%" /v "{56784854-C6CB-462B-8169-88E350ACB882}" /t REG_SZ /d "%UF%\Contacts" /f >nul 2>nul
reg add "%USF%" /v "{56784854-C6CB-462B-8169-88E350ACB882}" /t REG_EXPAND_SZ /d "%UF%\Contacts" /f >nul 2>nul

::音乐(Music)
for /f "tokens=3,*" %%i in ('reg query "%SF%" /v "My Music"') do set "Music=%%j"
robocopy "%Music%" "%UF%\Music" /e /copyall /move >nul 2>nul
reg add "%SF%" /v "My Music" /t REG_SZ /d "%UF%\Music" /f >nul 2>nul
reg add "%USF%" /v "My Music" /t REG_EXPAND_SZ /d "%UF%\Music" /f >nul 2>nul
reg add "%USF%" /v "{A0C69A99-21C8-4671-8703-7934162FCF1D}" /t REG_EXPAND_SZ /d "%UF%\Music" /f >nul 2>nul

::搜索(Searches)
for /f "tokens=2,*" %%i in ('reg query "%SF%" /v "{7D1D3A04-DEBB-4115-95CF-2F29DA2920DA}"') do set "Searches=%%j"
robocopy "%Searches%" "%UF%\Searches" /e /copyall /move >nul 2>nul
reg add "%SF%" /v "{7D1D3A04-DEBB-4115-95CF-2F29DA2920DA}" /t REG_SZ /d "%UF%\Searches" /f >nul 2>nul
reg add "%USF%" /v "{7D1D3A04-DEBB-4115-95CF-2F29DA2920DA}" /t REG_EXPAND_SZ /d "%UF%\Searches" /f >nul 2>nul

::文档(Documents)
for /f "tokens=2,*" %%i in ('reg query "%SF%" /v "Personal"') do set "Documents=%%j"
robocopy "%Documents%" "%UF%\Documents" /e /copyall /move >nul 2>nul
reg add "%SF%" /v "Personal" /t REG_SZ /d "%UF%\Documents" /f >nul 2>nul
reg add "%USF%" /v "Personal" /t REG_EXPAND_SZ /d "%UF%\Documents" /f >nul 2>nul
reg add "%USF%" /v "{F42EE2D3-909F-4907-8871-4C22FC0BF756}" /t REG_EXPAND_SZ /d "%UF%\Documents" /f >nul 2>nul

::链接(Links)
for /f "tokens=2,*" %%i in ('reg query "%SF%" /v "{BFB9D5E0-C6A9-404C-B2B2-AE6DB6AF4968}"') do set "Links=%%j"
robocopy "%Links%" "%UF%\Links" /e /copyall /move >nul 2>nul
reg add "%SF%" /v "{BFB9D5E0-C6A9-404C-B2B2-AE6DB6AF4968}" /t REG_SZ /d "%UF%\Links" /f >nul 2>nul
reg add "%USF%" /v "{BFB9D5E0-C6A9-404C-B2B2-AE6DB6AF4968}" /t REG_EXPAND_SZ /d "%UF%\Links" /f >nul 2>nul

::保存的游戏(Saved Games)
for /f "tokens=2,*" %%i in ('reg query "%SF%" /v "{4C5C32FF-BB9D-43B0-B5B4-2D72E54EAAA4}"') do set "Games=%%j"
robocopy "%Games%" "%UF%\Saved Games" /e /copyall /move >nul 2>nul
reg add "%SF%" /v "{4C5C32FF-BB9D-43B0-B5B4-2D72E54EAAA4}" /t REG_SZ /d "%UF%\Saved Games" /f >nul 2>nul
reg add "%USF%" /v "{4C5C32FF-BB9D-43B0-B5B4-2D72E54EAAA4}" /t REG_EXPAND_SZ /d "%UF%\Saved Games" /f >nul 2>nul

::下载(Downloads)
for /f "tokens=2,*" %%i in ('reg query "%SF%" /v "{374DE290-123F-4565-9164-39C4925E467B}"') do set "Downloads=%%j"
if "%Downloads%" EQU "%UD%\Downloads" goto :OldUsers
robocopy "%Downloads%" "%UD%\Downloads" /e /copyall /move >nul 2>nul
reg add "%SF%" /v "{374DE290-123F-4565-9164-39C4925E467B}" /t REG_SZ /d "%UD%\Downloads" /f >nul 2>nul
reg add "%USF%" /v "{374DE290-123F-4565-9164-39C4925E467B}" /t REG_EXPAND_SZ /d "%UD%\Downloads" /f >nul 2>nul
reg add "%USF%" /v "{7D83EE9B-2244-4E70-B1F5-5393042AF1E4}" /t REG_EXPAND_SZ /d "%UD%\Downloads" /f >nul 2>nul

:OldUsers
::删除原用户文件夹
if "%OldUsers%" EQU "%USERPROFILE%" goto :End
cd\
attrib -s -h -r "%OldUsers%"
rd /q /s "%OldUsers%"
if exist "%OldUsers%" goto :Start

:：删除原系统用户文件夹下文件夹
rd /q /s "%USERPROFILE%\Videos" >nul 2>nul
rd /q /s "%USERPROFILE%\Pictures" >nul 2>nul
rd /q /s "%USERPROFILE%\Desktop" >nul 2>nul
rd /q /s "%USERPROFILE%\Contacts" >nul 2>nul
rd /q /s "%USERPROFILE%\Favorites" >nul 2>nul
rd /q /s "%USERPROFILE%\Music" >nul 2>nul
rd /q /s "%USERPROFILE%\Searches" >nul 2>nul
rd /q /s "%USERPROFILE%\Downloads" >nul 2>nul
rd /q /s "%USERPROFILE%\Documents" >nul 2>nul
rd /q /s "%USERPROFILE%\Links" >nul 2>nul
rd /q /s "%USERPROFILE%\Saved Games" >nul 2>nul
rd /q /s "%USERPROFILE%\3D Objects" >nul 2>nul

:End
start "" explorer.exe